一、Write方法
Response 对象的Write 方法可以向发往客户端浏览器的HTML 文件中直接输出信息。也就是说，Reponse 对象的Write 方法将信息从 Web 服务器输出到浏览器。其语法格式如下：
Responser.Write Variant注解： Variant 参数值可以包含任何有效的HTML标记，但不能包括字符组合%>，如果要在浏览器显示的信息中包含符号：%>，则必须写为：%>，以免被视为ASP代码的结束标记。 使用VBSxript编写脚本时，由于VBScript 的静态字符串常量的长度不能大于1022个字节，所以，若要使用 Write 方法来输出长度超过1022个字符的内容，则不能使用字符串常量作为参数，而应当使用其他形式（如变量）来引用该内容。 在编写时，Response.Write 可以用”＝“来替代。例如，<% Response.Write Y %>也可以写成<% = Y %>。 Response.Write 方法与 VBScript 中的Document.Write 方法功能相似，其区别在于：Response 对象是ASP内置对象，其Write 方法的功能是从Web 服务器向客户端浏览器输出数据；Document 是浏览器对象 ，其 Write 方法的功能是直接向浏览器输出数据。
实例一：本例使用Response Write 方法向客户端浏览器输出了一个完整的HTML文件。代码如下：
<% @ Language="vbscript" %>
<%
Response.Write "<HTML>"
Response.Write "<HEAD>"
Response.Write "<TITLE>Response对象Write方法的应用实例</TITLE>"
Response.Write "</HEAD>"
Response.Write "<BODY>"
Response.Write "<CENTER>"
Response.Write "<font color='red' size='6' face='华文彩云'>**留意你的宝石**</font>"
Response.Write "</CENTER>"
Response.Write "<hr size='2' color='green' width=70%>"
Response.Write "<font color='#cc9999' size='5'>"
Response.Write" 上帝是公平的，无论对谁，都赐予一个盛着宝物的锦囊，那里面装有时间、健康、梦幻、激情、才干等足以让我们开创美好生活的宝石，有的人感激于上帝的馈赠，用这些宝石来换取更多的宝石，而有的人却很轻易地扔掉了这些宝石；最终弄得两手空空，只留下一串羡慕、追悔、抱怨……<br>"
Response.Write"别随手扔掉你的宝石。从现在开始，弯下腰来，攥紧拳头，播撒汗水，去寻觅、去思索、去创造，用上帝赐予你的锦囊去获取生命中更多的瑰宝！"
Response.Write "</font>"
Response.Write "</BODY>"
Response.Write "</HTML>"
%>二、重定向网址
Response对象的Redirect 方法可以使浏览器从当前网页转向到其他网页。其语法格式如下：
Response.Redirect 路径注解：
”路径“是指新网页的网址； 由于 Response.Redirect 的作用是告诉浏览器打开新网页，所以Response.Redirect 必须放在没有数据输出到浏览器之前，换句话说，Response.Redirect 就放在程序的<HTML>标记前面，若要在<html>标记后调用它，则必须将Response.Buffer属性为True。实例二：本实例通过系统时钟判断当前时间是不是大于或等于凌晨5点，而且小于或等于19点，若是则重定向到4-2c1.htm页面，否则重定向到4-2c2.htm页面。代码如下：
<% @ Language=VBScript %>
<%Response.Buffer=True %>
<html>
<body>
<%
myTime=time()
if myTime>=#5:00:00# and mytime<=#19:00:00# then
PageName="4-2c1.htm"
else
PageName="4-2c2.htm"
end if
Response.Redirect PageName
%>
</body>
</html>4-2c1.htm页面代码如下：
<html>
<head><title>现在是开放网站时间</title></head>
<body>
<font color="red" size="7" face="华文彩云" align="center"><b> 欢迎光临本网站！</b></font>
</body>
</html>4-2C2.htm页面代码如下：
<html>
<head><title>现在是关闭网站时间</title></head>
<body>
<font color="green" size="7" face="华文彩云" align="center"><b> 本网站每天的17点到凌晨5点是休站时间。谢谢合作！</b></font>
</body>
</html>三、Response 的End 方法
Responser 对象用End 方法可以结束 ASP 程序的运行。其语法格式如下：
Response.End实例三：通过设置网页的有效时间段，若超过了该时间段，则显示相应的信息，并结束程序的执行，而不显示网页的内容。其代码如下（文件名：4-2d.asp)：
<% @ Language=VBScript %>
<%Response.Buffer=True %>
<%
myTime=time()
if myTime<=#5:00:00# or mytime>=#19:00:00# then
Response.Write "<font color='green' size='7' face='华文彩云' align='center'>现在时间为"
Response.Write myTime
Response.Write "<p>网页开放时间为凌晨5点到晚上7点。目前暂不开放！</p>"
Response.End
end if
%>
<html>
<body>
<center><p>现在时间为<%=myTime %></P>
<font size="7" face="华文彩云" color="red">欢迎光临！</font><p>
<a href="4-2-3.asp">返回教材</a>
</center>
</body>
</html>四、Response 的Clear方法
Clear方法用于清除缓冲区中的所有HTML输出，可以用来防止显示第二个页面时，第一个页面也显示出来。它把第一个页面从Buffer中清空了。但Clear 方法只清除响应正文而不清除响应标题。可以用该方法处理错误情况。但如果将Response.Buffer设置为True,则该方法将导致运行时错误。其语法格式如下：
Response.Clear实例四：本实例将Buffer设为True.但没有调用Response的Clear方法。代码如下(文件名：4-2e.asp)：
<% Response.Buffer=true %>
<html>
<head><title>Response 输出时使用缓冲页示例</title></head>
<body>
<p align="center">Response 输出时使用缓冲页
<br><br></p>
<%
startTime=Timer
for I=1 to 20000
Response.Write "使用缓冲"
Next
EndTime=timer
interval=EndTime-startTime
'Response.Clear
Response.write "<center><p><font size='7' face='华文彩云' color='green'>本页面将Buffer设置为True.</font><p>"
Response.Write "<b>花费时间为" & Interval & "秒。</b></center>"
%>
<center><a href="4-2-3.asp">返回教材</a></center>
</body>
</html>实例五：本实例将Buffer设为True.而且调用了Response的Clear方法。这样在调用Clear方法之前缓冲区的内容都被清除了，在页面中不会显示出来。其代码与例四的代码相似，只是将前‘Response.Clear前的注释标记 ' 去掉了。(文件名：4-2e.asp)：
五、Response 的Flush方法
Flush方法可以立即发送缓冲区中的输出。如果没有将Response.Buffer 设置为True，该方法将导致运行时错误。其语法格式如下:
Response.Flush实例六：本实例调用Response.Flush方法，立即将缓冲区的输出发送给浏览器。代码如下：<% Response.Buffer=true %>
<html>
<head><title>Response 输出时使用缓冲页示例</title></head>
<body>
<div align="center">
Response 输出时使用缓冲页
<br><br></p>
<%
startTime=Timer
for I=1 to 2000
Response.Write "使用缓冲"
Response.Flush
Next
EndTime=timer
interval=EndTime-startTime
Response.write "<center><p><font size='7' face='华文彩云' color='green'>本页面调用了Response.Flush方法。结果缓冲不作用，信息输出时间比使用缓冲页要长.</font><p>"
Response.Write "<b>花费时间为" & Interval & "秒。</b></center>"
%>
</div>
<p>
<center><a href="4-2-3.asp">返回教材</a></center>
</body>
</html>
| Word教程网 | Excel教程网 | Dreamweaver教程网 | Fireworks教程网 | PPT教程网 | FLASH教程网 | PS教程网 |
| HTML教程网 | DIV CSS教程网 | FLASH AS教程网 | ACCESS教程网 | SQL SERVER教程网 | C语言教程网 | JAVASCRIPT教程网 |
| ASP教程网 | ASP.NET教程网 | CorelDraw教程网 |
QQ：2693987339(点击联系)购买教程光盘
:
