Flash as3设计模式之单例模式

什么是单例模式？

在面向对象的编程中，有时候会要求一个类有且仅存在一个实例，并提供一个全局的访问方法。所以我们在设计这样的类的时候，就需要思考如何避开构造函数，提供一种机制来实现单例（单一实例）。这就是单例模式。另因为在Flash as3中无法操作线程，因此我们无需考虑多线程情况下的单例。

单例模式的几种Flash as3实现

在Flash as3中有多种方法可以实现Singleton模式。

方法1：
[CODE]
package {
     public class Singleton {
         private static  var _instance:Singleton = new Singleton();
         public function Singleton() {
             if (_instance) {
                 throw new Error("只能用getInstance()来获取实例");
             }
         }
         public static function getInstance():Singleton {
            return _instance;
        }
   }
}[/CODE]
此方法通过静态私有变量_instance来创建Singleton类的实例，通过getInstance方法来访问这个单一实例。另外，由于在Flash as3中不允许private、protected的构造函数，只能是public，因此需要防止用构造函数来创建Singleton类的实例。这个方法有个问题就是这个类的实例会在程序一开始就创建。

方法2：
[CODE]
package {
     public class Singleton {
         private static  var _singleton:Boolean=true;
         private static  var _instance:Singleton;
         public function Singleton() {
             if (_singleton) {
                 throw new Error("只能用getInstance()来获取实例");
             }
         }
        public static function getInstance():Singleton{
            if (!_instance) {
                _singleton=false;
                _instance=new Singleton();
                _singleton=true;
            }
            return _instance;
        }
    }
}[/CODE]
此方法通过一个静态私有变量_singleton来控制_instance的创建，保证其唯一性。并且这个方法不存在方法1中的问题，_instance实例只有在调用getInstance()方法后才会创建。

方法3：
[CODE]
package {
     public class Singleton {
         private static  var singleton : Singleton;
         public function Singleton( caller : Function = null ) {
             if ( caller != hidden ) {
                 throw new Error("只能用getInstance()来获取实例");
             }
             if ( Singleton.singleton != null ) {
                 throw new Error("只能用getInstance()来获取实例");
            }
        }
        public static function getInstance():Singleton {
            if ( singleton == null ) {
                singleton = new Singleton( hidden );
            }
            return singleton;
        }
        private static function hidden():void {
        }
    }
}[/CODE]
此方法通过对构造函数增加参数来控制单个实例的创建。此构造函数只有传入参数为私有方法hidden的时候，才能创建实例。私有方法hidden对外的不可见性保证了单例的实现。

方法4：
[CODE]
package {
     public class Singleton {
         private static  var _instance:Singleton;
         public function Singleton(singletoner:Singletoner) {
             if (singletoner == null) {
                 throw new Error("只能用getInstance()来获取实例");
             }
         }
         public static function getInstance():Singleton {
            if (_instance == null) {
                _instance = new Singleton(new Singletoner());
            }
            return _instance;
        }
    }
}
internal class Singletoner {
}
[/CODE]
此方法和方法3相似。这里利用了包外类对外的不可见性（Singletoner类仅在此as文件内可见）来保证单例的实现。

总结

单例模式的实现方式很多，在不同的需求下选择合适的才是最好的。比如方法1虽然一开始就会创建实例，但它不会像其他方法每次调用实例都要检查是否存在类的实例。Singleton模式只考虑实例的创建，而没有考虑到销毁，由垃圾回收机制自行处理。另外，你也可以扩展Singleton模式，比如稍做修改保证一个类只有少数几个实例，来实现一些特殊的目的，这样做也是合理和有意义的。