深入学习Flash as中使用Function的高级技巧（二）

深入学习Flash as中使用Function的高级技巧（二）

如果大家在学习Flash as中喜欢我这个高级技巧专题，那么日后会陆续发布一些我自己这几年来项目开发笔记中的实用技巧。

利用函数返回函数：
有一个proxyObject对象，我们希望根据proxy对象的内容来确定一个方法，来处理myObject对象。
当proxyObject是字符串时，我们又希望根据它字符串的内容来确定返回不同的函数(或方法)。这些函数参数和类型是不完全相同的，有的可能是一个参数，有的可能是多个参数，不同类型。
那么传统的解决方法：在函数内部调用其他函数就显得力不从心。即使解决，也不如我下面chooseFuncBy()这个函数简洁。
缺点当然有，那就是比较灵活，你一定要清楚管理好每个目标函数和判断逻辑。因为这种灵活的编程方式编译器是无法检查，不能查出类型不匹配这种错误的。菜鸟慎用。
复制内容到剪贴板
代码:
//通过A调用只有一个参数的aFunc():
chooseFuncBy("A")("A func has only one parameter.");
//输出：aFunc():A func has only one parameter.
//通过B调用有两个参数的bFunc():
chooseFuncBy("B")("B func has two parameters.","No.2 parameter");
//输出：bFunc():B func has two parameters.  one more Parameter:No.2 parameter
//字符串不符，默认函数
chooseFuncBy("wu lala")("I choose A function");
//输出：Welcome to Kingda.org! My blog
var withObj:Object = new Object();
var myObj:Object = {name:"黑羽", blog:"http;//www.kingda.org", hobby:"Starcraft"};
chooseFuncBy(withObj)(myObj);
/* 输出：
objectFunc():
name:黑羽
blog:http;//www.kingda.org
hobby:Starcraft
*/
function chooseFuncBy(inputString):Function {
   
    //运用一：利用参数的种类来确定返回的函数
    if (!(typeof(inputString) == "string")) {
        return objectFunc;
    }
   
    //运用二：根据参数内容来返回函数
    switch (inputString) {
        case "A":
            return aFunc;
        case "B":
            return bFunc;   
        default:
            return kingdaFunc;
    }
    //更多延伸运用：利用参数个数、instanceof确定不同Class的实例来选择函数等等
}
function aFunc(nS:String):Void {
    trace ("aFunc():" + nS);   
}
function bFunc(nS:String, nP:String):Void {
    trace ("bFunc():" + nS + "  one more Parameter:"+ nP);   
}
function kingdaFunc():Void {
    trace ("Welcome to Kingda.org! My blog");
}
function objectFunc(kingdaObj:Object):Void {
    trace ("objectFunc():");
    for (var i in kingdaObj) {
        trace ( i + ":" + kingdaObj[i]);
    }
}