关于Flash as3中出现的强大事件机制四

1.EventDispatcher和Event的简介。
Flash as3中Object是万物之宗母，且生养众多，共有220多个子类。Event(事件类)和EventDispatcher(事件发送者类)就是在这一代之中。 Event和EventDispatcher是事件机制的两大主角，二者缺一不可。
Event类及其子类的功能就是提供各种具体的事件供EventDispatcher使用，不能干别的。
EventDispatcher则是要让它所有的子类都能发送事件。
那么，Flash as3就让所有要发送事件的类都统统继承于EventDispatcher。而需要发送事件的类毫无疑问，都是些很重要的类，比如URLLoader，DisplayObject。
其中DisplayObject更是一代霸父，所有可视对象，比如MovieClip,Spirit等等等等统统都是它的子孙。
因此，父以子贵，EventDispatcher在Object的第一代子女中，位高权重，影响极大。

2. 回顾 Flash as2.0中发送事件
Flash as2.0中发送事件是怎么干的？
在类中留几个函数对象，如 dispatchEvent:Function，再搞一个EventDispatcher.initialize()来初始化一下要发送事件的类，然后，就搞定了。.....好简单。
但Flash as3中更简单，更加标准。

3.继承EventDispatcher进行事件发送。
继承是最方便最快的一种。
刚刚说过了，所有的可视对象都继承DisplayObject,是EventDispatcher的孙子辈，因此都可以直接使用dispatchEvent()来发送事件了。
看代码，我们让一个普通的MovieClip， KingdaMC，来发送一个莫名其妙的事件，比如说"KingdaPlaySC"。

KingdaMC.dispatchEvent(new Event("KingdaPlaySC"));

现在我们要让一个我们自己的类来发送事件。

//以下为一个名叫KingdaSampleClass的Document Class,请自行和一个Fla绑定。
//如果忘了怎么弄，看我第三篇教程

package {
    import flash.display.Sprite;
    import flash.events.Event;

    public class KingdaSampleClass extends Sprite {

        public function KingdaSampleClass() {
            //生成一个KingdaSampleDispatcher的实例
   var dispatcher:KingdaSampleDispatcher = new KingdaSampleDispatcher();
           
   //标准的实现
   dispatcher.addEventListener(KingdaSampleDispatcher.ACTION, actionHandler);
            dispatcher.doSomething();
   
   //可以用直接字符串标识事件类型，但推荐使用静态加const的字符串
   dispatcher.addEventListener("KingdaPlaySC", anotherHandler); 
           
   //直接用new Event生成一个新的事件对象，该对象的事件类型为"KingdaPlaySC"
   dispatcher.dispatchEvent(new Event("KingdaPlaySC"));
   //输出：
   //action的侦听器: [Event type="action" bubbles=false cancelable=false eventPhase=2]
   //KingdaPlaySC的侦听器: [Event type="KingdaPlaySC" bubbles=false cancelable=false eventPhase=2]
        }

        private function actionHandler(event:Event):void {
            trace("action的侦听器: " + event);
        }
  
  private function anotherHandler(event:Event):void {
            trace("KingdaPlaySC的侦听器: " + event);
        }
    }
}

import flash.events.EventDispatcher;
import flash.events.Event;

class KingdaSampleDispatcher extends EventDispatcher {
    public static var ACTION:String = "action";

    //如果你需要在自己类中某个方法中发送事件，那么示例如下
 public function doSomething():void {
  //你的代码.....
  
  //发送事件
               dispatchEvent(new Event(KingdaSampleDispatcher.ACTION));
    }
}